内気なもんた君

時々日本語化してます

アイコンキャッシュの再構築

Tips

アイコンキャッシュの再構築

フォルダーのカスタマイズやコンテキストメニューのカスタマイズなどをしていると、アイコンキャッシュを再構築してエクスプローラーを再起動したい時が往々にしてあります。

 

ついでなんで、

  • アイコンキャッシュ(再構築)
  • サムネイルキャッシュ(縮小表示)
  • テンポラリフォルダー
  • フォルダーの表示設定

これらをまとめて削除します。

 

フォルダーの表示設定とは
HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags
以下にある数字キーです。

このほか、
HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\BagMRU
HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\MuiCache
もついでに削除します。

 

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -

@echo off
openfiles > nul 2>&1
if errorlevel 1 (
   PowerShell.exe -Command Start-Process ""%0"" -Verb runas
   exit
)

taskkill /f /im explorer.exe
del /a:h /f /q %localappdata%\IconCache.db > nul 2>&1
del /a:i /f /q %localappdata%\Microsoft\Windows\Explorer\iconcache* > nul 2>&1
del /a:i /f /q %localappdata%\Microsoft\Windows\Explorer\thumbcache* > nul 2>&1
rd %TEMP% /q /s > nul 2>&1
del /q /s /f "%SystemRoot%\Temp\*" && for /d %%i in ("%SystemRoot%\Temp\*") do @rd /q /s "%%i"
del /q /s /f "%LOCALAPPDATA%\Temp\*" && for /d %%i in ("%LOCALAPPDATA%\Temp\*") do @rd /q /s "%%i"
ie4uinit.exe -show

for /f "tokens=1 delims=" %%i in ('reg query "HKCU\Software\Classes\Local Settings\Software\Microsoft\Windows\Shell\Bags" ^| findstr /r /c:"\\Bags\\[1-9]"') do reg delete "%%i" /f > nul
start explorer.exe

 

- = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = - = -

上記コマンドを、アイコンキャッシュの再構築.cmd などという名前で保存して実行してください。

前回同様、管理者権限で実行されます。